按更新时间同步单个文件的简易方案

我曾经抱怨过，有个很简单的单个文件同步需求，却居然难以找到有软件能够解决。也许是需求太过于简单，反而没人去考虑。连 Allway Sync 这么好的东西，也做不到。于是一直都是人肉解决。

最近有点厌倦了每次 Copy 来 Copy 去的事情。而且中间也不是没有出过错。一出错就会丢一次的数据。索性简单地写了个 bat 批处理脚本来解决这种事情：

@echo off
xcopy D:\仓库\文件.txt .\ /D /Y >nul
xcopy .\文件.txt D:\仓库\ /D /Y >nul

运行这个 bat 脚本后，更新时间比较早的那个副本，会被另外一个覆盖掉。接下来只要每次编辑前或编辑后都记得运行一下这个脚本，就可以使两边文件版本一致，不需要再考虑复制方向对不对的问题了。

写了个批量测试服务器 Ping 值的小工具

不时有人问我要 hosts，但是很多时候也不敢贸然的给。担心泄漏是一方面。另外一方面，我这边可以用的 hosts，在别人那边可能用不了。我这边用起来很快的 hosts，在人家那边可能像乌龟爬。叫别人 ping 一下当然不是什么太麻烦的事情，但如果连试好几个 IP 都不行，有时候也是很头大的事。效率也很低下。

因此想，要是有个能批量 Ping，并且能很容易看到输出结果的工具，就好了。用批处理做个批量 Ping 是很容易的，但结果并不是特别一目了然。于是干脆自己动手做了一个。

启动时会加载当前目录下的 server.list 文件，文件中每行写一个地址（这几个地址有些人可能一看就知道是什么东西了）就可以了。写域名也是可以的，但我这里输出结果中并不包含域名解析的结果。
目前只打算简单做成这样，反正只当小工具用用。如果觉得网络不顺的时候，就启动起来跑一跑看看。然后也可以把一堆 IP 丢给别人自己校验去。

有需求的朋友可以去拿来用下。工具的下载地址：Dropbox镜像 Mega下载页面
为了减少 CRT 依赖性，上面的发布版本是静态链接的。如果想用动态链接版本，或者担心木马、病毒什么的，就下载下面的源代码自己编译吧。VC6 就可以。反正自己也没写多少代码，许可证什么的就懒得去弄了。
源代码下载地址：Dropbox镜像 Mega下载页面

自己写了个帮助快速替换 hosts 的工具

替换 hosts 对于会的人而言并不是一件复杂的事情。不过仍然稍嫌繁琐：目录本来就比较深，还要涉及到文件复制和改名。稍一不留意还有搞错掉的可能。

两个月前，我终于无法忍受了，自己写了一个批处理来解决这个问题。人容易出错，人会烦，机器不会出错——如果你程序写对了的情况下。作为程序员，就应该有自己动手丰衣足食的觉悟。因此就有了 SetHosts.bat 的第一版：

@echo off
pushd %SystemRoot%\system32\drivers\etc\
copy /y %1 hosts
popd

只这样显然是不够的。在命令行下敲指令，这不是我的初衷。虽然 Windows 的 Drag & Drop 可以省很多事情，但我还想做得更多。把这个 BAT 注册成某个特定后缀的文件的默认打开程序不是很好吗？这样以后直接双击文件就可以完成替换了。

于是当时我自己用 regedit 在注册表上填写了关联文件打开方式的相关信息。现在我可以双击 hosts_cn.fkw 或 hosts_us.fkw 来快速地应用某个我事先准备好的 hosts 文件了。
应该说，自己用用，这样是足够了。不过我还想做的更好一点。让程序自己完成这个填写注册表的过程，不是更好吗？于是有了 SetHosts.bat 的第二版：

@echo off
if {%1}=={} goto install
if {%1}=={/u} goto uninstall
if {%1}=={/U} goto uninstall
pushd %SystemRoot%\system32\drivers\etc\
copy /y %1 hosts
popd
goto :eof
:install
set MY_TEMPREGFILE=%TEMP%\temp.reg
set MY_SETHOST=%~f0
set MY_SETHOST=%MY_SETHOST:\=\\%
echo Windows Registry Editor Version 5.00>%MY_TEMPREGFILE%
echo.>>%MY_TEMPREGFILE%
echo [HKEY_CLASSES_ROOT\.fkw]>>%MY_TEMPREGFILE%
echo @="Fuckwall.Hosts">>%MY_TEMPREGFILE%
echo [HKEY_CLASSES_ROOT\Fuckwall.Hosts]>>%MY_TEMPREGFILE%
echo [HKEY_CLASSES_ROOT\Fuckwall.Hosts\shell]>>%MY_TEMPREGFILE%
echo [HKEY_CLASSES_ROOT\Fuckwall.Hosts\shell\edit]>>%MY_TEMPREGFILE%
echo [HKEY_CLASSES_ROOT\Fuckwall.Hosts\shell\edit\command]>>%MY_TEMPREGFILE%
echo @="\"C:\\Windows\\Notepad.exe\" \"%%1\"">>%MY_TEMPREGFILE%
echo [HKEY_CLASSES_ROOT\Fuckwall.Hosts\shell\open]>>%MY_TEMPREGFILE%
echo [HKEY_CLASSES_ROOT\Fuckwall.Hosts\shell\open\command]>>%MY_TEMPREGFILE%
echo @="\"%MY_SETHOST%\" \"%%1\"">>%MY_TEMPREGFILE%
regedit /s %MY_TEMPREGFILE%
del /q %MY_TEMPREGFILE%
set MY_TEMPREGFILE=
set MY_SETHOST=
echo 处理程序安装成功
echo 您可以双击后缀名为fkw的文件来直接更换hosts
echo.
pause
goto :eof
:uninstall
set MY_TEMPREGFILE=%TEMP%\temp.reg
echo Windows Registry Editor Version 5.00>%MY_TEMPREGFILE%
echo.>>%MY_TEMPREGFILE%
echo [-HKEY_CLASSES_ROOT\.fkw]>>%MY_TEMPREGFILE%
echo [-HKEY_CLASSES_ROOT\Fuckwall.Hosts]>>%MY_TEMPREGFILE%
echo [-HKEY_CLASSES_ROOT\Fuckwall.Hosts\shell]>>%MY_TEMPREGFILE%
echo [-HKEY_CLASSES_ROOT\Fuckwall.Hosts\shell\edit]>>%MY_TEMPREGFILE%
echo [-HKEY_CLASSES_ROOT\Fuckwall.Hosts\shell\edit\command]>>%MY_TEMPREGFILE%
echo [-HKEY_CLASSES_ROOT\Fuckwall.Hosts\shell\open]>>%MY_TEMPREGFILE%
echo [-HKEY_CLASSES_ROOT\Fuckwall.Hosts\shell\open\command]>>%MY_TEMPREGFILE%
regedit /s %MY_TEMPREGFILE%
del /q %MY_TEMPREGFILE%
set MY_TEMPREGFILE=
echo 处理程序反安装成功
pause
goto :eof

这下不仅注册有了，注销（反安装）也有了。以后看到 fkw 后缀的文件，就可以快速地 Fuckwall 了。……于是今天方校长就请病假了。

如果整代码有困难，那么可以从下面两个链接之一进行下载：
Dropbox: https://dl.dropboxusercontent.com/u/44933633/SetHosts.bat
Mega: https://mega.co.nz/#!Bhx2yYoR!ElR26mi-iGqx5WU3YJks8ViINKEE_wlv1Y32Mil6UEU